public with sharing class OpportunitiesService
{
   public static void applyDiscounts(Set<Id> opportunityIds, Decimal discountPercentage)
   {
        // Validate parameters
        if(opportunityIds == null || opportunityIds.size() == 0)
        {
            throw new OpportunityServiceException('Opportunities not specified.');
        }

        if(discountPercentage < 0 || discountPercentage > 100)
        {
            throw new OpportunityServiceException('Invalid discount to apply.');
        }

        // Query Opportunities and Lines (SOQL inlined for this example, see Selector pattern in later module)
        List<Opportunity> opportunities =[select Amount, (select UnitPrice from OpportunityLineItems)
             from Opportunity where Id in :opportunityIds];

        // Update Opportunities and Lines (if present)
        List<Opportunity> oppsToUpdate = new List<Opportunity>();
        List<OpportunityLineItem> oppLinesToUpdate = new List<OpportunityLineItem>();

        Decimal factor = 1 - (discountPercentage == null ? 0 : discountPercentage / 100);

        for(Opportunity opportunity : opportunities)
        {
            // Apply to Opportunity Amount
            if(opportunity.OpportunityLineItems != null && opportunity.OpportunityLineItems.size() > 0)
            {
                for(OpportunityLineItem oppLineItem : opportunity.OpportunityLineItems)
                {
                    oppLineItem.UnitPrice = oppLineItem.UnitPrice * factor;
                    oppLinesToUpdate.add(oppLineItem);
                }
            }
            else
            {
                opportunity.Amount = opportunity.Amount * factor;
                oppsToUpdate.add(opportunity);
            }
        }

        // Update the database
        SavePoint sp = Database.setSavePoint();

        try
        {
            update oppLinesToUpdate;
            update oppsToUpdate;
        }
        catch (Exception e)
        {
            // Rollback
            Database.rollback(sp);
            // Throw exception on to caller
            throw e;
        }
    }

    public class OpportunityServiceException extends Exception {}
}

注意：

上图中没有提到 Apex Trigger，因为 Trigger 的逻辑属于 Domain layer，它和 Object 联系非常
紧密，在 Domain 层的业务逻辑通过 platform UI 或者 APIs 或多或少的会和 Service 层联系到一
起

public PageReference applyDiscount()
{
    try
    {
        // Apply discount entered to the current
        Opportunity  OpportunitiesService.applyDiscounts(new Set<ID>{ standardController.getId() }, DiscountPercentage);
    }
    catch (Exception e)
    {
        ApexPages.addMessages(e);
    }

    return ApexPages.hasMessages() ? null : standardController.view();
}

public PageReference applyDiscounts()
{
    try
    {
        // Apply discount entered to the selected Opportunities
        OpportunitiesService.applyDiscounts(
           // Tip: Creating a Map from an SObject list gives easy access to the Ids (keys)
           new Map<Id,SObject>(standardSetController.getSelected()).keyValues(),
           DiscountPercentage
        );
    }
    catch (Exception e)
    {
        ApexPages.addMessages(e);
    }

    return ApexPages.hasMessages() ? null : standardController.view();
}

public with sharing class OpportunityApplyDiscountJob implements Database.Batchable<SObject>
{
    public Decimal DiscountPercentage { get; private set; }

    public OpportunityApplyDiscountJob(Decimal discountPercentage)
    {
        // Discount to apply in this job
        this.DiscountPercentage = discountPercentage;
    }

    public Database.QueryLocator start(Database.BatchableContext ctx)
    {
        // Opportunities to discount
        return Database.getQueryLocator('select Id from Opportunity where StageName = \'Negotiation/Review\'');
    }

    public void execute(Database.BatchableContext BC, List<sObject> scope)
    {
        try
        {
          // Call the service
          OpportunitiesService.applyDiscounts(
            new Map<Id,SObject>(scope).keySet(),DiscountPercentage);
        }
        catch (Exception e)
        {
            // Email error, log error, chatter error etc..
        }
    }

    public void finish(Database.BatchableContext ctx) { }
}

public class OpportunityController
{
    @RemoteAction
    public static void applyDiscount(Id opportunityId, Decimal discountPercent)
    {
        // Call service
        OpportunitiesService.applyDiscounts(new Set<ID> { opportunityId }, discountPercent);
    }
}

作为一个 salesforce developer 不能仅仅停留在为客户解决一些业务逻辑方
面的问题，并且作为一个公司产品的后端程序猿，更为重要的是当产品迭代到一定
程度，随着难度的加大以及业务复杂度的加深，我们需要在开发中融入一些重要的
编程核心的思想，方便及时发现产品中的 bug 以及对产品后期可扩展性方面都有
不错的提升。

salesforce  层级分类如下：

 * 业务逻辑层（Business Logic Layer）
    非编码(Declarative): Formula, Validation, Workflow, Process Builder, Sharing Rules
    遍码(Coding): Apex Services, Apex Custom Actions

 * 数据处理层 （Data Access layer）
    非编码(Declarative): Data Loaders
    编码(Coding): SOQL, SOSL, Salesforce APIs

 * 数据库层 （Database Layer）
    非编码(Declarative): Custom Objects, Fields, Relationships, Rollups
    编码(Coding): Apex Triggers